#!/bin/csh -f
#
# "I wrote this."  --pink
#
set progname = ${0}
set progname = ${progname:t}
set usage = "Usage: ${progname} [-h[elp]] command start end [offset]"

if ($# < 1 ) then
    echo $usage
    exit 1
endif

if ("${argv[1]}" == "-h" || "${argv[1]}" == "-help") then
    cat <<EOF
${progname} v20050809 - pinkwerks - a divison of pink

Description :
    ${progname} is a multi-purpose looping t00l.

${usage}
    Things in "[]" are optional arguments

Where:
    command  skeleton command to loop
    start    start numbes
    end      end number

Command notes:
    #'s are replaced with padded integers.
    Commands with argvs must be quoted.

Example:
    ${progname} "mv thing.# widget.####" 1 10
 
    Gives you:
	mv thing.1 widget.0001 
	mv thing.2 widget.0002 
	mv thing.3 widget.0003 
        ...

EOF
    exit 1
endif

if ($# < 3 ) then
    echo "${usage}"
    exit 1
endif

set cmd = ($1)
@ fs = $2
@ fe = $3

while (${fs} <= ${fe})
    @ tmpfs = ${fs}
    @ i = 1
    set exec = ""
    while ( $i <= $#cmd )
	set count = `echo ${cmd[$i]} | sed -e 's,#,#\n,g' | grep \# | wc -l`
	set pad = `printf %${count}.${count}d ${tmpfs}`
	set word = `echo $cmd[$i] | sed -e "s,#*#,$pad,"`
	@ i ++
	set exec = ($exec $word)
    end
    echo $exec
    $exec
    @ fs ++
end